@echo off
setlocal enabledelayedexpansion

rem Sicherstellen, dass das Skript im Verzeichnis IPMITOOL_WIN gestartet wird
cd /d "%~dp0"

rem Sicherstellen, dass das LOG-Verzeichnis existiert
if not exist "LOG" (
    mkdir "LOG"
)

rem Zeitstempel für die Log-Datei
for /f %%i in ('powershell -NoProfile -Command "Get-Date -Format yyyyMMdd_HHmmss"') do set "TIMESTAMP=%%i"
set "LOG_FILE=LOG\wortmannag_log_%TIMESTAMP%.txt"

rem Überprüfen, ob der IPMI-Treiber bereits installiert ist
driverquery | findstr /i "imbdrv" >nul
if errorlevel 1 (
    echo IPMI-Treiber nicht gefunden. Installiere IPMI-Treiber...
    call install.bat
    timeout /t 5 /nobreak >nul
) else (
    echo IPMI-Treiber bereits installiert. Überspringe die Installation.
)

rem Ausführen der ipmitool-Befehle und Speichern der Ausgaben
echo Führe ipmitool-Befehle aus und speichere die Ausgaben in %LOG_FILE%...

echo. >> "%LOG_FILE%"
echo === FRU === >> "%LOG_FILE%"
ipmitool.exe fru >> "%LOG_FILE%"

echo. >> "%LOG_FILE%"
echo === CHASSIS STATUS=== >> "%LOG_FILE%"
ipmitool.exe chassis status >> "%LOG_FILE%"

echo. >> "%LOG_FILE%"
echo === POWER STATUS=== >> "%LOG_FILE%"
ipmitool.exe power status >> "%LOG_FILE%"

echo. >> "%LOG_FILE%"
echo === SDR === >> "%LOG_FILE%"
ipmitool.exe sdr elist >> "%LOG_FILE%"

echo. >> "%LOG_FILE%"
echo === SEL === >> "%LOG_FILE%"
ipmitool.exe sel elist >> "%LOG_FILE%"

echo Alle Befehle wurden ausgeführt. Die Ausgaben befinden sich in %LOG_FILE%.

rem Seriennummer des Systems ermitteln
for /f "tokens=2 delims==" %%s in ('wmic bios get serialnumber /value') do set "SERIALNUMBER=%%s"

rem Bestätigungsmeldung anzeigen
echo Logfile erfolgreich erstellt: %LOG_FILE%
echo Bitte senden Sie das Logfile an support@wortmann.de mit dem Betreff "Seriennummer %SERIALNUMBER%".
